This repository has no description
1.8 kB
54 lines
1# llm-agents' orca with a working darwin launcher. Upstream links
2# bin/orca-ide straight to Orca.app/Contents/MacOS/Orca; Electron then looks
3# for its helper apps relative to the symlink and dies with "Unable to find
4# helper app". Executing the binary by its real path inside the bundle works.
5{
6 lib,
7 stdenvNoCC,
8 runtimeShell,
9 fetchurl,
10 llm-agents,
11}:
12# stablyai deleted the v1.4.225 and v1.4.226 releases, so llm-agents' src 404s.
13# Fails the evaluation once llm-agents moves past them, so the pin gets dropped.
14assert lib.assertMsg (
15 llm-agents.orca.version == "1.4.226"
16) "llm-agents now ships orca ${llm-agents.orca.version}; remove the 1.4.224 pin in pkgs/orca";
17let
18 version = "1.4.224";
19 platforms = {
20 x86_64-linux = {
21 file = "orca-ide_${version}_amd64.deb";
22 hash = "sha256-8Dolyl9dHc5Nl5uCOGXevEC0ikGYsbqAbR9KtXYHbAo=";
23 };
24 aarch64-linux = {
25 file = "orca-ide_${version}_arm64.deb";
26 hash = "sha256-89BqCDSQaJzTymaIHtJwfHj2MTTSptk5KEruAFov/NE=";
27 };
28 aarch64-darwin = {
29 file = "Orca-${version}-arm64-mac.zip";
30 hash = "sha256-3tqvPVAipAYnHA0JpL6l2jsXwu32DpGcfkqxKDrXqBQ=";
31 };
32 };
33 platform = platforms.${stdenvNoCC.hostPlatform.system};
34 pinned = llm-agents.orca.overrideAttrs {
35 inherit version;
36 src = fetchurl {
37 url = "https://github.com/stablyai/orca/releases/download/v${version}/${platform.file}";
38 inherit (platform) hash;
39 };
40 };
41in
42if stdenvNoCC.hostPlatform.isDarwin then
43 pinned.overrideAttrs (old: {
44 postInstall = (old.postInstall or "") + ''
45 rm $out/bin/orca-ide
46 cat >$out/bin/orca-ide <<EOF
47 #!${runtimeShell}
48 exec "$out/Applications/Orca.app/Contents/MacOS/Orca" "\$@"
49 EOF
50 chmod +x $out/bin/orca-ide
51 '';
52 })
53else
54 pinned