This repository has no description
2.9 kB
94 lines
1{ self, pkgs, ... }:
2{
3 imports = [
4 ../../2configs
5 ../../2configs/network-manager.nix
6 ../../2configs/pipewire.nix
7 ../../2configs/yubikey.nix
8 ../../2configs/tpm2.nix
9 ../../2configs/desktops/sway/default.nix
10 ../../2configs/power-action.nix
11 ../../2configs/sunshine.nix
12 ../../2configs/rtl-sdr.nix
13 ../../2configs/browsers.nix
14 ../../2configs/container-bridge.nix
15 ../../2configs/android-webcam.nix
16 ../../2configs/radicle.nix
17 ../../2configs/steam.nix
18 ../../2configs/auto-timezone.nix
19 ];
20 system.stateVersion = "25.05";
21
22 boot.tmp.cleanOnBoot = true;
23
24 krebs.build.host = self.inputs.stockholm.kartei.hosts.xerxes;
25
26 environment.systemPackages = [
27 pkgs.bitwarden-desktop
28 pkgs.rbw
29 # retroarch with patched dolphin core (fixes shader compiler thread issue)
30 (pkgs.retroarch.withCores (
31 _cores:
32 builtins.filter (c: c.pname or "" != "libretro-dolphin") pkgs.retroarch-free.cores
33 ++ [ self.packages.${pkgs.system}.libretro-dolphin ]
34 ))
35 pkgs.pavucontrol
36 pkgs.claude-code
37 pkgs.ripgrep
38 self.packages.${pkgs.system}.mpv
39 self.packages.${pkgs.system}.s
40 pkgs.gh
41 ];
42
43 documentation.nixos.enable = true;
44 lass.workspace-manager.enable = true;
45
46 services.ollama =
47 let
48 gpuTargets = [ "gfx1100" ]; # Radeon 890M (gfx1150/RDNA 3.5) - only build for fallback target
49 customRocblas = pkgs.rocmPackages.rocblas.override {
50 withHipBlasLt = false; # hipblaslt takes extremely long to build; rocblas's own Tensile kernels work fine
51 inherit gpuTargets;
52 };
53 customRocsparse = pkgs.rocmPackages.rocsparse.override {
54 inherit gpuTargets;
55 };
56 customRocsolver = pkgs.rocmPackages.rocsolver.override {
57 inherit gpuTargets;
58 rocblas = customRocblas;
59 rocsparse = customRocsparse;
60 };
61 customHipblas = pkgs.rocmPackages.hipblas.override {
62 rocblas = customRocblas;
63 rocsolver = customRocsolver;
64 rocsparse = customRocsparse;
65 };
66 customRocmPackages = pkgs.rocmPackages // {
67 rocblas = customRocblas;
68 hipblas = customHipblas;
69 rocsolver = customRocsolver;
70 rocsparse = customRocsparse;
71 };
72 in
73 {
74 enable = true;
75 package = pkgs.ollama-rocm.override {
76 rocmGpuTargets = gpuTargets;
77 rocmPackages = customRocmPackages;
78 };
79 environmentVariables = {
80 HSA_OVERRIDE_GFX_VERSION = "11.0.0"; # Radeon 890M (gfx1150/RDNA 3.5) - fallback to gfx1100
81 OLLAMA_NUM_CTX = "16384"; # 48 GiB RAM shared with GPU; 32k OOMs with 32B model
82 };
83 };
84
85 # extra-container for testing declarative containers without full rebuilds
86 programs.extra-container.enable = true;
87
88 nix.settings.trusted-users = [
89 "root"
90 "lass"
91 ];
92
93 systemd.services.nix-daemon.environment.SSH_AUTH_SOCK = "/run/user/1000/ssh-tpm-agent.sock";
94}