This repository has no description
1.5 kB
61 lines
1{
2 lib,
3 buildGoModule,
4 fetchFromGitea,
5 go_1_27,
6 nix-update-script,
7}:
8
9# go.mod requires go 1.27; nixpkgs' default go is still 1.26.
10(buildGoModule.override { go = go_1_27; }) (
11 finalAttrs:
12 let
13 rev = "d6f2505b0d84e3feb5d4ef8d12d3ded45c178f62";
14 in
15 {
16 pname = "parley";
17 version = "0.5.0-unstable-2026-10-11";
18
19 src = fetchFromGitea {
20 domain = "git.mills.io";
21 owner = "prologic";
22 repo = "parley";
23 inherit rev;
24 hash = "sha256-QDFhmP25pACb9gGic7QpwX0FzRoh2Tdsn7U7M8LPbag=";
25 };
26
27 vendorHash = "sha256-siSavE8i/Rh6LfI+HXhyKsPrbfyncJCcEYJsA4KZ378=";
28
29 # modernc.org/sqlite is pure Go; upstream builds static binaries.
30 env.CGO_ENABLED = 0;
31
32 # The generated templ components and the compiled stylesheet are
33 # committed upstream, so neither templ nor tailwind is needed here.
34 subPackages = [
35 "cmd/parleyd"
36 "cmd/parleyctl"
37 ];
38
39 ldflags = [
40 "-s"
41 "-w"
42 "-X main.Version=${finalAttrs.version}"
43 "-X main.Commit=${builtins.substring 0 7 rev}"
44 ];
45
46 passthru.updateScript = nix-update-script {
47 extraArgs = [
48 "--flake"
49 "--version=branch"
50 ];
51 };
52
53 meta = {
54 description = "Federated, decentralised chat that speaks plain IRC";
55 homepage = "https://git.mills.io/prologic/parley";
56 license = lib.licenses.mit;
57 mainProgram = "parleyd";
58 platforms = lib.platforms.unix;
59 };
60 }
61)