This repository has no description
3.7 kB
110 lines
1{ config, pkgs, ... }:
2{
3 systemd.services.borgbackup-job-hetzner.serviceConfig.ReadWritePaths = [
4 "/var/log/telegraf"
5 ];
6
7 clan.core.vars.generators.borgbackup = {
8 files."borgbackup.ssh.id25519" = { };
9 files."borgbackup.ssh.id25519.pub".secret = false;
10 runtimeInputs = with pkgs; [
11 coreutils
12 openssh
13 ];
14 script = ''
15 ssh-keygen -t ed25519 -N "" -f $out/borgbackup.ssh.id25519
16 '';
17 };
18
19 # Ensure backup directory exists for pg_dump
20 systemd.tmpfiles.rules = [
21 "d /var/backup 0700 root root -"
22 "d /var/backup/postgresql 0700 root root -"
23 "d /var/backup/parley 0700 root root -"
24 ];
25
26 services.borgbackup.jobs.hetzner = {
27 paths = [
28 "/var/backup"
29 "/var/lib/bitwarden_rs"
30 "/var/lib/htgen-cyberlocker"
31 "/var/lib/htgen-paste"
32 "/var/lib/matrix-synapse/media_store/local_content"
33 "/var/lib/radicale"
34 "/home/bot"
35 "/var/vmail"
36 "/var/dkim"
37 "/var/sieve"
38 "/var/lib/heisenbridge"
39 # identity.key also lives in clan vars; the SQLite databases are
40 # dumped consistently to /var/backup/parley by the preHook.
41 "/var/lib/parley"
42 ];
43 exclude = [
44 "*.pyc"
45 "/home/bot/.cache"
46 "/home/bot/.nix-defexpr"
47 "/home/bot/.nix-profile"
48 "/var/lib/parley/*.db*"
49 ];
50 repo = "u550643@u550643.your-storagebox.de:/./neoprism";
51 encryption.mode = "none";
52 compression = "auto,zstd";
53 startAt = "*-*-* 03:00:00";
54 environment.BORG_RSH =
55 let
56 knownHostsFile = pkgs.writeText "storagebox-known-hosts" ''
57 [u550643.your-storagebox.de]:23 ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIICf9svRenC/PLKIL9nk6K/pxQgoiFC41wTNvoIncOxs
58 '';
59 in
60 "ssh -oPort=23 -oUserKnownHostsFile=${knownHostsFile} -i ${
61 config.clan.core.vars.generators.borgbackup.files."borgbackup.ssh.id25519".path
62 }";
63
64 readWritePaths = [
65 "/var/backup"
66 "/var/lib/hedgedoc"
67 # WAL-mode SQLite readers need to write the -shm file
68 "/var/lib/parley"
69 ];
70
71 preHook = ''
72 set -x
73 # Dump matrix-synapse PostgreSQL database (14GB, compresses well)
74 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
75 matrix-synapse | ${pkgs.gzip}/bin/gzip > /var/backup/postgresql/matrix-synapse.sql.gz
76
77 # Dump bridge PostgreSQL databases — portal mappings, sessions, tokens.
78 # Losing these = relogin everywhere + every existing Matrix room orphaned.
79 for db in mautrix-whatsapp mautrix-signal mautrix-telegram mautrix-discord; do
80 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
81 "$db" | ${pkgs.gzip}/bin/gzip > "/var/backup/postgresql/$db.sql.gz"
82 done
83
84 # Dump hedgedoc SQLite database (172MB) safely
85 ${pkgs.sqlite}/bin/sqlite3 /var/lib/hedgedoc/db.sqlite ".backup /var/backup/hedgedoc.sqlite"
86
87 # Dump parley accounts + history SQLite databases safely
88 for db in parley history; do
89 ${pkgs.sqlite}/bin/sqlite3 "/var/lib/parley/$db.db" ".backup /var/backup/parley/$db.db"
90 done
91
92 # Dump timeful polls (when.lassul.us) from MongoDB
93 ${pkgs.mongodb-tools}/bin/mongodump --uri=mongodb://127.0.0.1:27017 \
94 --db=schej-it --gzip --archive=/var/backup/timeful.archive.gz
95 '';
96
97 postHook = ''
98 cat > /var/log/telegraf/borgbackup-job-hetzner.service <<EOF
99 task,frequency=daily last_run=$(date +%s)i,state="$([[ $exitStatus == 0 ]] && echo ok || echo fail)"
100 EOF
101 '';
102
103 prune.keep = {
104 within = "1d";
105 daily = 7;
106 weekly = 4;
107 monthly = 0;
108 };
109 };
110}