This repository has no description
3.0 kB
96 lines
1{ config, pkgs, ... }:
2{
3 systemd.services.borgbackup-job-hetzner.serviceConfig.ReadWritePaths = [
4 "/var/log/telegraf"
5 ];
6
7 clan.core.vars.generators.borgbackup = {
8 files."borgbackup.ssh.id25519" = { };
9 files."borgbackup.ssh.id25519.pub".secret = false;
10 runtimeInputs = with pkgs; [
11 coreutils
12 openssh
13 ];
14 script = ''
15 ssh-keygen -t ed25519 -N "" -f $out/borgbackup.ssh.id25519
16 '';
17 };
18
19 # Ensure backup directory exists for pg_dump
20 systemd.tmpfiles.rules = [
21 "d /var/backup 0700 root root -"
22 "d /var/backup/postgresql 0700 root root -"
23 ];
24
25 services.borgbackup.jobs.hetzner = {
26 paths = [
27 "/var/backup"
28 "/var/lib/bitwarden_rs"
29 "/var/lib/htgen-cyberlocker"
30 "/var/lib/htgen-paste"
31 "/var/lib/matrix-synapse/media_store/local_content"
32 "/var/lib/radicale"
33 "/home/bot"
34 "/var/lib/kannix"
35 "/var/vmail"
36 "/var/dkim"
37 "/var/sieve"
38 "/var/lib/heisenbridge"
39 ];
40 exclude = [
41 "*.pyc"
42 "/home/bot/.cache"
43 "/home/bot/.nix-defexpr"
44 "/home/bot/.nix-profile"
45 "/var/lib/kannix/.cache"
46 ];
47 repo = "u550643@u550643.your-storagebox.de:/./neoprism";
48 encryption.mode = "none";
49 compression = "auto,zstd";
50 startAt = "*-*-* 03:00:00";
51 environment.BORG_RSH =
52 let
53 knownHostsFile = pkgs.writeText "storagebox-known-hosts" ''
54 [u550643.your-storagebox.de]:23 ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIICf9svRenC/PLKIL9nk6K/pxQgoiFC41wTNvoIncOxs
55 '';
56 in
57 "ssh -oPort=23 -oUserKnownHostsFile=${knownHostsFile} -i ${
58 config.clan.core.vars.generators.borgbackup.files."borgbackup.ssh.id25519".path
59 }";
60
61 readWritePaths = [
62 "/var/backup"
63 "/var/lib/hedgedoc"
64 ];
65
66 preHook = ''
67 set -x
68 # Dump matrix-synapse PostgreSQL database (14GB, compresses well)
69 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
70 matrix-synapse | ${pkgs.gzip}/bin/gzip > /var/backup/postgresql/matrix-synapse.sql.gz
71
72 # Dump bridge PostgreSQL databases — portal mappings, sessions, tokens.
73 # Losing these = relogin everywhere + every existing Matrix room orphaned.
74 for db in mautrix-whatsapp mautrix-signal mautrix-telegram mautrix-discord; do
75 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
76 "$db" | ${pkgs.gzip}/bin/gzip > "/var/backup/postgresql/$db.sql.gz"
77 done
78
79 # Dump hedgedoc SQLite database (172MB) safely
80 ${pkgs.sqlite}/bin/sqlite3 /var/lib/hedgedoc/db.sqlite ".backup /var/backup/hedgedoc.sqlite"
81 '';
82
83 postHook = ''
84 cat > /var/log/telegraf/borgbackup-job-hetzner.service <<EOF
85 task,frequency=daily last_run=$(date +%s)i,state="$([[ $exitStatus == 0 ]] && echo ok || echo fail)"
86 EOF
87 '';
88
89 prune.keep = {
90 within = "1d";
91 daily = 7;
92 weekly = 4;
93 monthly = 0;
94 };
95 };
96}