This repository has no description
1.1 kB
45 lines
1{
2 lib,
3 rustPlatform,
4 fetchFromGitHub,
5 pkg-config,
6 nettle,
7 nix-update-script,
8}:
9rustPlatform.buildRustPackage (finalAttrs: {
10 pname = "age-plugin-gpg";
11 version = "0.1.0";
12
13 src = fetchFromGitHub {
14 owner = "CertainLach";
15 repo = "age-plugin-gpg";
16 rev = "v${finalAttrs.version}";
17 hash = "sha256-HfCl+YAjKPNFtLAHjNyjlHhRxD85qZLWsfKzqORtj5U=";
18 };
19
20 # Encrypt to keys that are only in the gpg keyring (no secret key or
21 # smartcard stub in gpg-agent), e.g. on hosts generating clan vars.
22 patches = [ ./keyring-fallback.patch ];
23
24 cargoLock = {
25 lockFile = "${finalAttrs.src}/Cargo.lock";
26 };
27
28 nativeBuildInputs = [
29 pkg-config
30 rustPlatform.bindgenHook
31 ];
32
33 buildInputs = [ nettle ];
34
35 passthru.updateScript = nix-update-script { extraArgs = [ "--flake" ]; };
36
37 meta = {
38 description = "Age plugin utilizing gpg-agent & keygrips as recipients/identities";
39 homepage = "https://github.com/CertainLach/age-plugin-gpg";
40 license = lib.licenses.mit;
41 mainProgram = "age-plugin-gpg";
42 platforms = lib.platforms.unix;
43 maintainers = [ ];
44 };
45})