This repository has no description
3.5 kB
103 lines
1{ config, pkgs, ... }:
2{
3 clan.core.vars.generators.borgbackup = {
4 files."borgbackup.ssh.id25519" = { };
5 files."borgbackup.ssh.id25519.pub".secret = false;
6 runtimeInputs = with pkgs; [
7 coreutils
8 openssh
9 ];
10 script = ''
11 ssh-keygen -t ed25519 -N "" -f $out/borgbackup.ssh.id25519
12 '';
13 };
14
15 # Ensure backup directory exists for pg_dump
16 systemd.tmpfiles.rules = [
17 "d /var/backup 0700 root root -"
18 "d /var/backup/postgresql 0700 root root -"
19 "d /var/backup/parley 0700 root root -"
20 ];
21
22 services.borgbackup.jobs.hetzner = {
23 paths = [
24 "/var/backup"
25 "/var/lib/bitwarden_rs"
26 "/var/lib/htgen-cyberlocker"
27 "/var/lib/htgen-paste"
28 "/var/lib/matrix-synapse/media_store/local_content"
29 "/var/lib/radicale"
30 "/home/bot"
31 "/var/vmail"
32 "/var/dkim"
33 "/var/sieve"
34 "/var/lib/heisenbridge"
35 # identity.key also lives in clan vars; the SQLite databases are
36 # dumped consistently to /var/backup/parley by the preHook.
37 "/var/lib/parley"
38 # WBO boards (paint.lassul.us). DynamicUser + StateDirectory make
39 # /var/lib/whitebophir only a symlink, so back up the real directory.
40 "/var/lib/private/whitebophir"
41 ];
42 exclude = [
43 "*.pyc"
44 "/home/bot/.cache"
45 "/home/bot/.nix-defexpr"
46 "/home/bot/.nix-profile"
47 "/var/lib/parley/*.db*"
48 ];
49 repo = "u550643@u550643.your-storagebox.de:/./neoprism";
50 encryption.mode = "none";
51 compression = "auto,zstd";
52 startAt = "*-*-* 03:00:00";
53 environment.BORG_RSH =
54 let
55 knownHostsFile = pkgs.writeText "storagebox-known-hosts" ''
56 [u550643.your-storagebox.de]:23 ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIICf9svRenC/PLKIL9nk6K/pxQgoiFC41wTNvoIncOxs
57 '';
58 in
59 "ssh -oPort=23 -oUserKnownHostsFile=${knownHostsFile} -i ${
60 config.clan.core.vars.generators.borgbackup.files."borgbackup.ssh.id25519".path
61 }";
62
63 readWritePaths = [
64 "/var/backup"
65 "/var/lib/hedgedoc"
66 # WAL-mode SQLite readers need to write the -shm file
67 "/var/lib/parley"
68 ];
69
70 preHook = ''
71 set -x
72 # Dump matrix-synapse PostgreSQL database (14GB, compresses well)
73 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
74 matrix-synapse | ${pkgs.gzip}/bin/gzip > /var/backup/postgresql/matrix-synapse.sql.gz
75
76 # Dump bridge PostgreSQL databases — portal mappings, sessions, tokens.
77 # Losing these = relogin everywhere + every existing Matrix room orphaned.
78 for db in mautrix-whatsapp mautrix-signal mautrix-telegram mautrix-discord; do
79 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
80 "$db" | ${pkgs.gzip}/bin/gzip > "/var/backup/postgresql/$db.sql.gz"
81 done
82
83 # Dump hedgedoc SQLite database (172MB) safely
84 ${pkgs.sqlite}/bin/sqlite3 /var/lib/hedgedoc/db.sqlite ".backup /var/backup/hedgedoc.sqlite"
85
86 # Dump parley accounts + history SQLite databases safely
87 for db in parley history; do
88 ${pkgs.sqlite}/bin/sqlite3 "/var/lib/parley/$db.db" ".backup /var/backup/parley/$db.db"
89 done
90
91 # Dump timeful polls (when.lassul.us) from MongoDB
92 ${pkgs.mongodb-tools}/bin/mongodump --uri=mongodb://127.0.0.1:27017 \
93 --db=schej-it --gzip --archive=/var/backup/timeful.archive.gz
94 '';
95
96 prune.keep = {
97 within = "1d";
98 daily = 7;
99 weekly = 4;
100 monthly = 0;
101 };
102 };
103}