This repository has no description
4.4 kB
142 lines
1{
2 config,
3 pkgs,
4 lib,
5 ...
6}:
7let
8 torrentport = 56709; # port forwarded in airvpn webinterface
9in
10{
11 clan.core.vars.password-store.secretLocation = "/var/state/secret-vars";
12
13 imports = [
14 ../../2configs
15 ../../2configs/retiolum.nix
16 ../../2configs/services/flix
17 ../../2configs/autoupdate.nix
18 ../../2configs/services/archiver-bot.nix
19 ];
20
21 # we need to configure another port for the mycelium admin interface, because it conflicts with sonarr.
22 services.mycelium.extraArgs = [
23 "--api-addr"
24 "127.0.0.1:9898"
25 ];
26
27 services.transmission.settings.peer-port = torrentport;
28 krebs.build.host = config.krebs.hosts.yellow;
29
30 krebs.sync-containers3.inContainer = {
31 enable = true;
32 pubkey = builtins.readFile ./facts/yellow.sync.pub;
33 };
34
35 networking.useHostResolvConf = false;
36 networking.useNetworkd = true;
37 # we need to set a namserver here that can be also be reached from the transmission network namespace
38 environment.etc."resolv.conf".text = ''
39 options edns0
40 nameserver 9.9.9.9
41 '';
42 services.resolved.enable = lib.mkForce false;
43
44 systemd.services."netns@" = {
45 description = "%I network namespace";
46 before = [ "network.target" ];
47 serviceConfig = {
48 Type = "oneshot";
49 RemainAfterExit = true;
50 ExecStart = "${pkgs.iproute2}/bin/ip netns add %I";
51 ExecStop = "${pkgs.iproute2}/bin/ip netns del %I";
52 };
53 };
54
55 systemd.services.transmission-netns = {
56 bindsTo = [ "netns@transmission.service" ];
57 after = [ "netns@transmission.service" ];
58 path = [
59 pkgs.iproute2
60 pkgs.wireguard-tools
61 ];
62 script = ''
63 set -efux
64 until ${pkgs.dig.host}/bin/host europe.vpn.airdns.org; do sleep; done
65
66 ip link del t2 || :
67 ip -n transmission link set lo up
68 ip link add airvpn type wireguard
69 ip -n transmission link del airvpn || :
70 ip link set airvpn netns transmission
71 ip -n transmission addr add 10.176.43.231/32 dev airvpn
72 ip -n transmission addr add fd7d:76ee:e68f:a993:41b3:846b:d271:30d8/128 dev airvpn
73 ip netns exec transmission wg syncconf airvpn <(wg-quick strip ${
74 config.clan.core.vars.generators.airvpn.files."airvpn.conf".path
75 })
76 ip -n transmission link set airvpn up
77 ip -n transmission route add default dev airvpn
78 ip -6 -n transmission route add default dev airvpn
79 ip link add t1 type veth peer name t2
80
81 ip -n transmission link del t1 || :
82 ip link set t1 netns transmission
83
84 ip addr add 128.0.0.2/30 dev t2
85 ip addr add fdb4:3310:947::1/64 dev t2
86 ip link set t2 up
87 ip -n transmission addr add 128.0.0.1/30 dev t1
88 ip -n transmission addr add fdb4:3310:947::2/64 dev t1
89 ip -n transmission link set t1 up
90 ip -n transmission route add 42:0:ce16::3110/16 via fdb4:3310:947::1 dev t1
91 '';
92 serviceConfig = {
93 RemainAfterExit = true;
94 Type = "oneshot";
95 };
96 };
97
98 clan.core.vars.generators.airvpn = {
99 files."airvpn.conf" = { };
100 prompts.config.description = ''
101 login into https://airvpn.org/ goto https://airvpn.org/generator/
102 generate a wireguard config
103 paste the config here
104 '';
105 runtimeInputs = with pkgs; [ coreutils ];
106 script = ''
107 cat "$prompts"/config > "$out"/airvpn.conf
108 '';
109 };
110
111 # so we can forward traffic from the transmission network namespace
112 boot.kernel.sysctl."net.ipv6.conf.all.forwarding" = 1;
113
114 systemd.services.transmission = {
115 after = [ "transmission-netns.service" ];
116 wants = [ "transmission-netns.service" ];
117 bindsTo = [ "netns@transmission.service" ];
118 serviceConfig = {
119 NetworkNamespacePath = "/var/run/netns/transmission";
120 # https://github.com/NixOS/nixpkgs/issues/258793
121 RootDirectoryStartOnly = lib.mkForce false;
122 RootDirectory = lib.mkForce "";
123 CPUSchedulingPolicy = "idle";
124 IOSchedulingClass = "idle";
125 IOSchedulingPriority = 7;
126 # increase file descriptor limit to handle many torrents/peers
127 LimitNOFILE = 65536;
128 };
129 };
130 clan.core.vars.generators.yellow-container = {
131 files."yellow.sync.key" = { };
132 files."yellow.sync.pub".secret = false;
133 runtimeInputs = with pkgs; [
134 coreutils
135 openssh
136 ];
137 script = ''
138 ssh-keygen -t ed25519 -N "" -f "$out"/yellow.sync.key
139 mv "$out"/yellow.sync.key.pub "$out"/yellow.sync.pub
140 '';
141 };
142}