This repository has no description
3.3 kB
100 lines
1{ config, pkgs, ... }:
2{
3 clan.core.vars.generators.borgbackup = {
4 files."borgbackup.ssh.id25519" = { };
5 files."borgbackup.ssh.id25519.pub".secret = false;
6 runtimeInputs = with pkgs; [
7 coreutils
8 openssh
9 ];
10 script = ''
11 ssh-keygen -t ed25519 -N "" -f $out/borgbackup.ssh.id25519
12 '';
13 };
14
15 # Ensure backup directory exists for pg_dump
16 systemd.tmpfiles.rules = [
17 "d /var/backup 0700 root root -"
18 "d /var/backup/postgresql 0700 root root -"
19 "d /var/backup/parley 0700 root root -"
20 ];
21
22 services.borgbackup.jobs.hetzner = {
23 paths = [
24 "/var/backup"
25 "/var/lib/bitwarden_rs"
26 "/var/lib/htgen-cyberlocker"
27 "/var/lib/htgen-paste"
28 "/var/lib/matrix-synapse/media_store/local_content"
29 "/var/lib/radicale"
30 "/home/bot"
31 "/var/vmail"
32 "/var/dkim"
33 "/var/sieve"
34 "/var/lib/heisenbridge"
35 # identity.key also lives in clan vars; the SQLite databases are
36 # dumped consistently to /var/backup/parley by the preHook.
37 "/var/lib/parley"
38 ];
39 exclude = [
40 "*.pyc"
41 "/home/bot/.cache"
42 "/home/bot/.nix-defexpr"
43 "/home/bot/.nix-profile"
44 "/var/lib/parley/*.db*"
45 ];
46 repo = "u550643@u550643.your-storagebox.de:/./neoprism";
47 encryption.mode = "none";
48 compression = "auto,zstd";
49 startAt = "*-*-* 03:00:00";
50 environment.BORG_RSH =
51 let
52 knownHostsFile = pkgs.writeText "storagebox-known-hosts" ''
53 [u550643.your-storagebox.de]:23 ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIICf9svRenC/PLKIL9nk6K/pxQgoiFC41wTNvoIncOxs
54 '';
55 in
56 "ssh -oPort=23 -oUserKnownHostsFile=${knownHostsFile} -i ${
57 config.clan.core.vars.generators.borgbackup.files."borgbackup.ssh.id25519".path
58 }";
59
60 readWritePaths = [
61 "/var/backup"
62 "/var/lib/hedgedoc"
63 # WAL-mode SQLite readers need to write the -shm file
64 "/var/lib/parley"
65 ];
66
67 preHook = ''
68 set -x
69 # Dump matrix-synapse PostgreSQL database (14GB, compresses well)
70 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
71 matrix-synapse | ${pkgs.gzip}/bin/gzip > /var/backup/postgresql/matrix-synapse.sql.gz
72
73 # Dump bridge PostgreSQL databases — portal mappings, sessions, tokens.
74 # Losing these = relogin everywhere + every existing Matrix room orphaned.
75 for db in mautrix-whatsapp mautrix-signal mautrix-telegram mautrix-discord; do
76 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
77 "$db" | ${pkgs.gzip}/bin/gzip > "/var/backup/postgresql/$db.sql.gz"
78 done
79
80 # Dump hedgedoc SQLite database (172MB) safely
81 ${pkgs.sqlite}/bin/sqlite3 /var/lib/hedgedoc/db.sqlite ".backup /var/backup/hedgedoc.sqlite"
82
83 # Dump parley accounts + history SQLite databases safely
84 for db in parley history; do
85 ${pkgs.sqlite}/bin/sqlite3 "/var/lib/parley/$db.db" ".backup /var/backup/parley/$db.db"
86 done
87
88 # Dump timeful polls (when.lassul.us) from MongoDB
89 ${pkgs.mongodb-tools}/bin/mongodump --uri=mongodb://127.0.0.1:27017 \
90 --db=schej-it --gzip --archive=/var/backup/timeful.archive.gz
91 '';
92
93 prune.keep = {
94 within = "1d";
95 daily = 7;
96 weekly = 4;
97 monthly = 0;
98 };
99 };
100}