This repository has no description
2.4 kB
72 lines
1{ self, ... }:
2{
3 perSystem =
4 { pkgs, system, ... }:
5 let
6 piPkg = self.legacyPackages.${system}.llm.pi;
7
8 # Pre-install pi plugins into a fake npm global prefix
9 pluginPrefixRaw =
10 pkgs.runCommand "pi-plugins-raw"
11 {
12 nativeBuildInputs = [
13 pkgs.nodejs
14 pkgs.cacert
15 ];
16 outputHashMode = "recursive";
17 outputHashAlgo = "sha256";
18 outputHash = "sha256-QZSVCJ0XirRz56v6ogxaB37c0bI8+OGEjrnqCFr/YI8=";
19 impureEnvVars = [
20 "http_proxy"
21 "https_proxy"
22 ];
23 SSL_CERT_FILE = "${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt";
24 }
25 ''
26 export HOME=$TMPDIR
27 export npm_config_prefix=$out
28 npm install -g pi-hooks shitty-extensions
29 '';
30
31 # Remove the resistance extension (annoying terminator quote widget)
32 pluginPrefix = pkgs.runCommand "pi-plugins" { } ''
33 cp -a ${pluginPrefixRaw} $out
34 chmod -R u+w $out
35 pkg=$out/lib/node_modules/shitty-extensions/package.json
36 ${pkgs.jq}/bin/jq '.pi.extensions |= map(select(contains("resistance") | not))' "$pkg" > "$pkg.tmp"
37 mv "$pkg.tmp" "$pkg"
38 '';
39 in
40 {
41 packages.pi = self.wrapLib.makeWrapper {
42 pkgs = pkgs;
43 package = piPkg;
44 runtimeInputs = [ pkgs.nodejs ];
45 wrapper =
46 { exePath, ... }:
47 ''
48 set -efu
49 export npm_config_prefix="${pluginPrefix}"
50
51 # Ensure settings.json has our plugins listed
52 SETTINGS_DIR="''${PI_CODING_AGENT_DIR:-$HOME/.pi/agent}"
53 SETTINGS_FILE="$SETTINGS_DIR/settings.json"
54 mkdir -p "$SETTINGS_DIR"
55
56 # Add packages to settings if not already present
57 if [ ! -f "$SETTINGS_FILE" ]; then
58 echo '{"packages":["npm:pi-hooks","npm:shitty-extensions"]}' > "$SETTINGS_FILE"
59 else
60 for pkg in "npm:pi-hooks" "npm:shitty-extensions"; do
61 if ! grep -q "$pkg" "$SETTINGS_FILE"; then
62 ${pkgs.jq}/bin/jq --arg p "$pkg" '.packages = ((.packages // []) + [$p] | unique)' "$SETTINGS_FILE" > "$SETTINGS_FILE.tmp"
63 mv "$SETTINGS_FILE.tmp" "$SETTINGS_FILE"
64 fi
65 done
66 fi
67
68 exec ${exePath} "$@"
69 '';
70 };
71 };
72}