forked from
lass.pds.lassul.us/superconfig
This repository has no description
4.1 kB
123 lines
1{
2 self,
3 config,
4 pkgs,
5 lib,
6 ...
7}:
8
9let
10 tincr = self.packages.${pkgs.system}.tincr;
11 tincrPkg = pkgs.runCommand "tincr-sbin-${tincr.version}" { version = tincr.version; } ''
12 mkdir -p $out
13 cp -r ${tincr}/* $out/
14 chmod -R u+w $out
15 ln -s bin $out/sbin
16 '';
17
18 # Peer keys and addresses come straight from kartei. This is only the host
19 # database -- the daemon stays on nixpkgs' services.tinc with pkgs/tincr
20 # swapped in (barnacle does the same with tincr's darwin module, see
21 # machines/barnacle/retiolum.nix).
22 #
23 # tincHosts is already filtered to SPTPS-capable nodes, so the RSA-only
24 # leftovers tincr refuses per connection attempt are gone.
25 kartei = import (self.inputs.kartei + "/modules/retiolum/hosts.nix") { inherit lib; };
26
27 name = config.networking.hostName;
28
29 # Nodes with no kartei card, known only inside superconfig. Exposes the same
30 # interface as kartei's hosts.nix, so both sources merge the same way.
31 local = self.retiolum;
32
33 own = kartei.own.${name} or local.own.${name};
34in
35
36{
37
38 networking.firewall.allowedTCPPorts = [ 655 ];
39 networking.firewall.allowedUDPPorts = [ 655 ];
40
41 services.tinc.networks.retiolum = {
42 package = tincrPkg;
43 # 1+ maps to per-packet Debug/Trace in tincr, which floods journald
44 # (tens of thousands of suppressed messages per minute) and rotates
45 # all other units' logs out of the journal within hours
46 debugLevel = 0;
47 hosts = kartei.tincHosts // local.tincHosts;
48 extraConfig = ''
49 AutoConnect = yes
50 LocalDiscovery = yes
51 '';
52 settings = {
53 Interface = "retiolum";
54 Name = name;
55 ConnectTo = [
56 "neoprism"
57 "ni"
58 "eve"
59 ];
60 };
61 };
62
63 # A changed tinc unit is restarted in switch-to-configuration's start phase
64 # instead of stopped up front: otherwise retiolum stays down for the whole
65 # stop phase (minutes when a unit like ipfs waits out its stop timeout) and
66 # takes the deploying ssh session over <machine>.r with it.
67 systemd.services."tinc.retiolum".stopIfChanged = false;
68
69 # Copy keys into the tinc config directory before tinc starts.
70 # Running before nixpkgs' preStart ensures key generation is skipped.
71 systemd.services."tinc.retiolum".preStart = lib.mkBefore ''
72 rm -f /etc/tinc/retiolum/rsa_key.priv /etc/tinc/retiolum/ed25519_key.priv /etc/tinc/retiolum/tinc-up
73 cp ${
74 config.clan.core.vars.generators.retiolum.files."retiolum.rsa_key.priv".path
75 } /etc/tinc/retiolum/rsa_key.priv
76 cp ${
77 config.clan.core.vars.generators.retiolum.files."retiolum.ed25519_key.priv".path
78 } /etc/tinc/retiolum/ed25519_key.priv
79 chown tinc-retiolum /etc/tinc/retiolum/rsa_key.priv /etc/tinc/retiolum/ed25519_key.priv
80 chmod 600 /etc/tinc/retiolum/rsa_key.priv /etc/tinc/retiolum/ed25519_key.priv
81 '';
82
83 clan.core.vars.generators.retiolum = {
84 files."retiolum.rsa_key.priv" = { };
85 files."retiolum.ed25519_key.priv" = { };
86 files."retiolum.rsa_key.pub".secret = false;
87 files."retiolum.ed25519_key.pub".secret = false;
88 runtimeInputs = with pkgs; [
89 coreutils
90 tinc_pre
91 ];
92 script = ''
93 tinc --config "$out" generate-keys 4096 >/dev/null
94 mv "$out"/rsa_key.priv "$out"/retiolum.rsa_key.priv
95 mv "$out"/ed25519_key.priv "$out"/retiolum.ed25519_key.priv
96 mv "$out"/rsa_key.pub "$out"/retiolum.rsa_key.pub
97 mv "$out"/ed25519_key.pub "$out"/retiolum.ed25519_key.pub
98 '';
99 };
100
101 systemd.network.networks.retiolum = {
102 matchConfig.Name = "retiolum";
103 address = lib.optional (own.ip4 != null) "${own.ip4}/16" ++ [ "${own.ip6}/16" ];
104 linkConfig = {
105 MTUBytes = "1377";
106 RequiredForOnline = "no";
107 };
108 networkConfig = {
109 LinkLocalAddressing = "no";
110 };
111 };
112
113 environment.systemPackages = [
114 tincrPkg
115 ];
116
117 # Upstream nixos/tinc preStart chowns hosts/ and invitations/ but not
118 # the network dir itself, so tincr (and tinc 1.1pre18) can't persist
119 # its address-cache there. Drop this once nixpkgs#520533 lands.
120 systemd.tmpfiles.rules = [
121 "z /etc/tinc/retiolum 0755 tinc-retiolum - -"
122 ];
123}