forked from
lass.pds.lassul.us/superconfig
This repository has no description
2.5 kB
88 lines
1{ config, pkgs, ... }:
2{
3 systemd.services.borgbackup-job-hetzner.serviceConfig.ReadWritePaths = [
4 "/var/log/telegraf"
5 ];
6
7 clan.core.vars.generators.borgbackup = {
8 files."borgbackup.ssh.id25519" = { };
9 files."borgbackup.ssh.id25519.pub".secret = false;
10 runtimeInputs = with pkgs; [
11 coreutils
12 openssh
13 ];
14 script = ''
15 ssh-keygen -t ed25519 -N "" -f $out/borgbackup.ssh.id25519
16 '';
17 };
18
19 # Ensure backup directory exists for pg_dump
20 systemd.tmpfiles.rules = [
21 "d /var/backup 0700 root root -"
22 "d /var/backup/postgresql 0700 root root -"
23 ];
24
25 services.borgbackup.jobs.hetzner = {
26 paths = [
27 "/var/backup"
28 "/var/lib/bitwarden_rs"
29 "/var/lib/htgen-cyberlocker"
30 "/var/lib/htgen-paste"
31 "/var/lib/matrix-synapse/media_store/local_content"
32 "/var/lib/radicale"
33 "/home/bot"
34 "/var/lib/kannix"
35 "/var/vmail"
36 "/var/dkim"
37 "/var/sieve"
38 ];
39 exclude = [
40 "*.pyc"
41 "/home/bot/.cache"
42 "/home/bot/.nix-defexpr"
43 "/home/bot/.nix-profile"
44 "/var/lib/kannix/.cache"
45 ];
46 repo = "u550643@u550643.your-storagebox.de:/./neoprism";
47 encryption.mode = "none";
48 compression = "auto,zstd";
49 startAt = "*-*-* 03:00:00";
50 environment.BORG_RSH =
51 let
52 knownHostsFile = pkgs.writeText "storagebox-known-hosts" ''
53 [u550643.your-storagebox.de]:23 ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIICf9svRenC/PLKIL9nk6K/pxQgoiFC41wTNvoIncOxs
54 '';
55 in
56 "ssh -oPort=23 -oUserKnownHostsFile=${knownHostsFile} -i ${
57 config.clan.core.vars.generators.borgbackup.files."borgbackup.ssh.id25519".path
58 }";
59
60 readWritePaths = [
61 "/var/backup"
62 "/var/lib/hedgedoc"
63 ];
64
65 preHook = ''
66 set -x
67 # Dump matrix-synapse PostgreSQL database (14GB, compresses well)
68 ${pkgs.sudo}/bin/sudo -u postgres ${config.services.postgresql.package}/bin/pg_dump \
69 matrix-synapse | ${pkgs.gzip}/bin/gzip > /var/backup/postgresql/matrix-synapse.sql.gz
70
71 # Dump hedgedoc SQLite database (172MB) safely
72 ${pkgs.sqlite}/bin/sqlite3 /var/lib/hedgedoc/db.sqlite ".backup /var/backup/hedgedoc.sqlite"
73 '';
74
75 postHook = ''
76 cat > /var/log/telegraf/borgbackup-job-hetzner.service <<EOF
77 task,frequency=daily last_run=$(date +%s)i,state="$([[ $exitStatus == 0 ]] && echo ok || echo fail)"
78 EOF
79 '';
80
81 prune.keep = {
82 within = "1d";
83 daily = 7;
84 weekly = 4;
85 monthly = 0;
86 };
87 };
88}