forked from
lass.pds.lassul.us/superconfig
This repository has no description
4.3 kB
124 lines
1{
2 self,
3 config,
4 pkgs,
5 lib,
6 ...
7}:
8
9let
10 tincr = self.packages.${pkgs.system}.tincr;
11 tincrPkg = pkgs.runCommand "tincr-sbin-${tincr.version}" { version = tincr.version; } ''
12 mkdir -p $out
13 cp -r ${tincr}/* $out/
14 chmod -R u+w $out
15 ln -s bin $out/sbin
16 '';
17
18 # Peer keys and addresses come straight from kartei. This is only the host
19 # database -- the daemon stays on nixpkgs' services.tinc with pkgs/tincr
20 # swapped in (barnacle does the same with tincr's darwin module, see
21 # machines/barnacle/retiolum.nix).
22 #
23 # tincHosts is already filtered to SPTPS-capable nodes, so the RSA-only
24 # leftovers tincr refuses per connection attempt are gone.
25 kartei = import (self.inputs.kartei + "/modules/retiolum/hosts.nix") { inherit lib; };
26
27 name = config.networking.hostName;
28 own = kartei.own.${name};
29in
30
31{
32
33 networking.firewall.allowedTCPPorts = [ 655 ];
34 networking.firewall.allowedUDPPorts = [ 655 ];
35
36 services.tinc.networks.retiolum = {
37 package = tincrPkg;
38 # 1+ maps to per-packet Debug/Trace in tincr, which floods journald
39 # (tens of thousands of suppressed messages per minute) and rotates
40 # all other units' logs out of the journal within hours
41 debugLevel = 0;
42 hosts = kartei.tincHosts;
43 extraConfig = ''
44 AutoConnect = yes
45 LocalDiscovery = yes
46 '';
47 settings = {
48 Interface = "retiolum";
49 Name = name;
50 ConnectTo = [
51 "neoprism"
52 "ni"
53 "eve"
54 ];
55 };
56 };
57
58 # A changed tinc unit is restarted in switch-to-configuration's start phase
59 # instead of stopped up front: otherwise retiolum stays down for the whole
60 # stop phase (minutes when a unit like ipfs waits out its stop timeout) and
61 # takes the deploying ssh session over <machine>.r with it.
62 systemd.services."tinc.retiolum".stopIfChanged = false;
63
64 # debugLevel 0 is still Info, and reconnect/MTU/path-revalidation chatter
65 # at Info floods journald; keep Warn and Error only. Target-scoped on
66 # purpose: `-d 0` sets the global directive and replaces a bare
67 # RUST_LOG=warn, while `tinc` prefix-matches every tinc* crate's target.
68 systemd.services."tinc.retiolum".environment.RUST_LOG = "tinc=warn";
69
70 # Copy keys into the tinc config directory before tinc starts.
71 # Running before nixpkgs' preStart ensures key generation is skipped.
72 systemd.services."tinc.retiolum".preStart = lib.mkBefore ''
73 rm -f /etc/tinc/retiolum/rsa_key.priv /etc/tinc/retiolum/ed25519_key.priv /etc/tinc/retiolum/tinc-up
74 cp ${
75 config.clan.core.vars.generators.retiolum.files."retiolum.rsa_key.priv".path
76 } /etc/tinc/retiolum/rsa_key.priv
77 cp ${
78 config.clan.core.vars.generators.retiolum.files."retiolum.ed25519_key.priv".path
79 } /etc/tinc/retiolum/ed25519_key.priv
80 chown tinc-retiolum /etc/tinc/retiolum/rsa_key.priv /etc/tinc/retiolum/ed25519_key.priv
81 chmod 600 /etc/tinc/retiolum/rsa_key.priv /etc/tinc/retiolum/ed25519_key.priv
82 '';
83
84 clan.core.vars.generators.retiolum = {
85 files."retiolum.rsa_key.priv" = { };
86 files."retiolum.ed25519_key.priv" = { };
87 files."retiolum.rsa_key.pub".secret = false;
88 files."retiolum.ed25519_key.pub".secret = false;
89 runtimeInputs = with pkgs; [
90 coreutils
91 tinc_pre
92 ];
93 script = ''
94 tinc --config "$out" generate-keys 4096 >/dev/null
95 mv "$out"/rsa_key.priv "$out"/retiolum.rsa_key.priv
96 mv "$out"/ed25519_key.priv "$out"/retiolum.ed25519_key.priv
97 mv "$out"/rsa_key.pub "$out"/retiolum.rsa_key.pub
98 mv "$out"/ed25519_key.pub "$out"/retiolum.ed25519_key.pub
99 '';
100 };
101
102 systemd.network.networks.retiolum = {
103 matchConfig.Name = "retiolum";
104 address = lib.optional (own.ip4 != null) "${own.ip4}/16" ++ [ "${own.ip6}/16" ];
105 linkConfig = {
106 MTUBytes = "1377";
107 RequiredForOnline = "no";
108 };
109 networkConfig = {
110 LinkLocalAddressing = "no";
111 };
112 };
113
114 environment.systemPackages = [
115 tincrPkg
116 ];
117
118 # Upstream nixos/tinc preStart chowns hosts/ and invitations/ but not
119 # the network dir itself, so tincr (and tinc 1.1pre18) can't persist
120 # its address-cache there. Drop this once nixpkgs#520533 lands.
121 systemd.tmpfiles.rules = [
122 "z /etc/tinc/retiolum 0755 tinc-retiolum - -"
123 ];
124}