forked from
lass.pds.lassul.us/superconfig
This repository has no description
2.7 kB
86 lines
1{ self, pkgs, ... }:
2{
3 imports = [
4 ../../2configs
5 ../../2configs/network-manager.nix
6 ../../2configs/pipewire.nix
7 ../../2configs/yubikey.nix
8 ../../2configs/tpm2.nix
9 ../../2configs/desktops/sway/default.nix
10 ../../2configs/power-action.nix
11 ../../2configs/sunshine.nix
12 ../../2configs/rtl-sdr.nix
13 ../../2configs/browsers.nix
14 ../../2configs/container-bridge.nix
15 ../../2configs/android-webcam.nix
16 ../../2configs/radicle.nix
17 ../../2configs/steam.nix
18 ];
19 system.stateVersion = "25.05";
20
21 boot.tmp.cleanOnBoot = true;
22
23 krebs.build.host = self.inputs.stockholm.kartei.hosts.xerxes;
24
25 environment.systemPackages = [
26 pkgs.bitwarden-desktop
27 pkgs.rbw
28 # retroarch with patched dolphin core (fixes shader compiler thread issue)
29 (pkgs.retroarch.withCores (
30 _cores:
31 builtins.filter (c: c.pname or "" != "libretro-dolphin") pkgs.retroarch-free.cores
32 ++ [ self.packages.${pkgs.system}.libretro-dolphin ]
33 ))
34 pkgs.pavucontrol
35 pkgs.claude-code
36 pkgs.ripgrep
37 self.packages.${pkgs.system}.mpv
38 self.packages.${pkgs.system}.s
39 pkgs.gh
40 ];
41
42 documentation.nixos.enable = true;
43 lass.workspace-manager.enable = true;
44
45 services.ollama =
46 let
47 gpuTargets = [ "gfx1100" ]; # Radeon 890M (gfx1150/RDNA 3.5) - only build for fallback target
48 customRocblas = pkgs.rocmPackages.rocblas.override {
49 withHipBlasLt = false; # hipblaslt takes extremely long to build; rocblas's own Tensile kernels work fine
50 inherit gpuTargets;
51 };
52 customRocsparse = pkgs.rocmPackages.rocsparse.override {
53 inherit gpuTargets;
54 };
55 customRocsolver = pkgs.rocmPackages.rocsolver.override {
56 inherit gpuTargets;
57 rocblas = customRocblas;
58 rocsparse = customRocsparse;
59 };
60 customHipblas = pkgs.rocmPackages.hipblas.override {
61 rocblas = customRocblas;
62 rocsolver = customRocsolver;
63 rocsparse = customRocsparse;
64 };
65 customRocmPackages = pkgs.rocmPackages // {
66 rocblas = customRocblas;
67 hipblas = customHipblas;
68 rocsolver = customRocsolver;
69 rocsparse = customRocsparse;
70 };
71 in
72 {
73 enable = true;
74 package = pkgs.ollama-rocm.override {
75 rocmGpuTargets = gpuTargets;
76 rocmPackages = customRocmPackages;
77 };
78 environmentVariables = {
79 HSA_OVERRIDE_GFX_VERSION = "11.0.0"; # Radeon 890M (gfx1150/RDNA 3.5) - fallback to gfx1100
80 OLLAMA_NUM_CTX = "16384"; # 48 GiB RAM shared with GPU; 32k OOMs with 32B model
81 };
82 };
83
84 # extra-container for testing declarative containers without full rebuilds
85 programs.extra-container.enable = true;
86}