forked from
lass.pds.lassul.us/superconfig
This repository has no description
3.1 kB
116 lines
1{
2 self,
3 pkgs,
4 ...
5}:
6let
7 send_to_radio = pkgs.writers.writeDashBin "send_to_radio" ''
8 ${pkgs.vorbis-tools}/bin/oggenc - |
9 ${
10 self.inputs.stockholm.packages.${pkgs.stdenv.hostPlatform.system}.cyberlocker-tools
11 }/bin/cput news.ogg
12 ${pkgs.curl}/bin/curl -fSs -X POST http://localhost:8002/newsshow
13 '';
14
15 gc_news = pkgs.writers.writeDashBin "gc_news" ''
16 set -xefu
17 export TZ=UTC #workaround for jq parsing wrong timestamp
18 ${pkgs.coreutils}/bin/cat $HOME/news | ${pkgs.jq}/bin/jq -cs 'map(select((.to|fromdateiso8601) > now)) | .[]' > $HOME/bla-news.tmp
19 ${pkgs.coreutils}/bin/mv $HOME/bla-news.tmp $HOME/news
20 '';
21
22 get_current_news = pkgs.writers.writeDashBin "get_current_news" ''
23 set -xefu
24 export TZ=UTC #workaround for jq parsing wrong timestamp
25 ${pkgs.coreutils}/bin/cat $HOME/news | ${pkgs.jq}/bin/jq -rs '
26 sort_by(.priority) |
27 map(select(
28 ((.to | fromdateiso8601) > now) and
29 (.from|fromdateiso8601) < now) |
30 .text
31 ) | .[]'
32 '';
33
34 newsshow =
35 pkgs.writers.writeDashBin "newsshow" # sh
36 ''
37 cat << EOF
38 hello crabpeople!
39 $(${pkgs.ddate}/bin/ddate +'Today is %{%A, the %e of %B%}, %Y. %N%nCelebrate %H')
40 It is $(date --utc +%H) o clock U.T.C.
41 todays news:
42 $(get_current_news)
43 $(gc_news)
44 EOF
45 '';
46in
47{
48 systemd.services.newsshow = {
49 path = [
50 newsshow
51 send_to_radio
52 gc_news
53 get_current_news
54 pkgs.retry
55 ];
56 script = ''
57 set -efu
58 retry -t 5 -d 10 -- newsshow |
59 retry -t 5 -d 10 -- /run/current-system/sw/bin/tts |
60 retry -t 5 -d 10 -- send_to_radio
61 '';
62 startAt = "*:00:00";
63 serviceConfig = {
64 User = "radio-news";
65 };
66 };
67
68 services.nginx.virtualHosts."radio-news.r" = {
69 locations."/" = {
70 proxyPass = "http://localhost:7999";
71 proxyWebsockets = true;
72 extraConfig = ''
73 add_header 'Access-Control-Allow-Origin' '*';
74 add_header 'Access-Control-Allow-Methods' 'GET, POST, OPTIONS';
75 '';
76 };
77 };
78 imports = [
79 ./tts.nix
80 ];
81 krebs.htgen.news = {
82 port = 7999;
83 user = {
84 name = "radio-news";
85 };
86 script = ". ${pkgs.writers.writeDash "htgen-news" ''
87 set -xefu
88 case "''${Method:-GET} $Request_URI" in
89 "GET /")
90 printf 'HTTP/1.1 200 OK\r\n'
91 printf 'Connection: close\r\n'
92 printf '\r\n'
93 cat "$HOME"/news | jq -sc .
94 exit
95 ;;
96 "POST /")
97 payload=$(head -c "$req_content_length")
98 printf '%s' "$payload" | jq 'has("from") and has("to") and has("text")' >&2
99 printf '%s' "$payload" | jq -c '{ from: .from, to: .to, text: .text, priority: (.priority // 0)}' >> "$HOME"/news
100 printf 'HTTP/1.1 200 OK\r\n'
101 printf 'Connection: close\r\n'
102 printf '\r\n'
103 exit
104 ;;
105 esac
106 ''}";
107 };
108
109 # debug
110 environment.systemPackages = [
111 send_to_radio
112 newsshow
113 get_current_news
114 gc_news
115 ];
116}